Lowest Low + Trendfilter

[CarlEkberg]

Tjena, jag håller på att köra lite tester intradag i 60 minuters upplösning men får inte rätt på det.
Jag vill köpa när jag har fått en 500 bars lägsta och när (MA20<MA50<MA100<MA200) inte gäller. Alltså alla gånger när MA:na inte är sorterade för nedgång.

Mitt ena köpscript ser ut såhär.

{portfölj}
ej_innehav:=le(portfolio(v),0)
kl905:=gt(Frac(Date()),0.384)
kl1720:=lt(Frac(Date()),0.722)

i60(
tid=and(kl905,kl1720)

{trigger}
LLX=eqv(L,LLV(L,500))

{köpsekvens}
köp1=and(tid,ej_innehav)
köp2=and(LLX,köp1)
köp3=and(köp2,le(GetGvar(5),0))

mult(köp3,5)
)

Mitt "trendscript" ser ut såhär.

close=cmpref(c,0,a)

{trigger sekvenser}
MA20=MOV(close,20,S)
MA50=MOV(close,50,S)
MA100=MOV(close,100,S)
MAPRIMAR=MOV(close,200,S)

{köpsekvens}
köp1=and(lt(MA20,MA50),lt(MA50,MA100))
köp2=and(köp1,lt(MA100,MAPRIMAR))
setGVarIF(köp2,5,1)

mult(köp2,5)

{@A(60,)}

Dock så verkar mitt köpscript inte alls ta hänsyn till mitt trendscript utan köper även när MA:na är sorterade för nedgång. Trendscriptet köper inget i ordermodellen.

Vad gör jag för fel?

Tack för hjälpen

[Bertil]

Tycker att du borde köra trendscriptet på i60 också. Testa det.
mvh
Bertil

[Henric]

Vet ej exakt vad du vill göra. Filter och trigger ger i alla fall signal i diagrammet.
Jag lade i hop scripten då de kör samma upplösning och det blir mer översiktligt.



ej_innehav:=le(portfolio(v),0)
kl905:=gt(Frac(Date()),0.384)
kl1720:=lt(Frac(Date()),0.722)


i60(
tid=and(kl905,kl1720)

{trigger filter}
MA20=MOV(c,20,S)
MA50=MOV(c,50,S)
MA100=MOV(c,100,S)
MAPRIMAR=MOV(c,200,S)
köp1=and(lt(MA20,MA50),lt(MA50,MA100))
köp2=and(köp1,lt(MA100,MAPRIMAR))


{trigger}
LLX=eqv(L,LLV(L,500))
köx1=and(1{tid},1{ej_innehav}) {vill rita och tar bort tid och position}
köx2=and(LLX,köx1)
köx3=and(köx2,köp2)

draw(mult(köp2,9),3,gsbF) {filter}
draw(mult(köx3,6),4,bsbF) {trigger}

add(0,0)

)

[CarlEkberg]

Tack för hjälpen, att lägga allt i samma script löste mitt problem.

Dock så förstår jag inte varför det inte skulle fungera att ha det i två olika script.