TRIX-graf

[jorgeng]

Lfm, hur har du fått till trix-grafen med %-fördelning? som visas i Scriptgalleriet/Genombrottsnivåer/Trix
för scriptet:

period:=10
m1:=mov(c,period,e)
m2:=mov(m1,period,e)
m3:=mov(m2,period,e)
mult(roc(m3,1,%),10)

Jag har testat lite med ppahslon:s trix-script, kan ev bli en ordermodell med sl-script. Dock har jag sett att ibland sker sälj på samma nivå som föregående köp-kurs några staplar senare.

Hur kan man få till ett script som stoppar köp/sälj om lastbuy/sell ej är större än en krona från föregående köp/sälj. Blir rörelsen större än en krona kan man ju vända positionen.

Köpscriptet ser nu ut så här:
period:=10
m1:=mov(C,period,e)
m2:=mov(m1,period,e)
m3:=mov(m2,period,e)
trixDay:=mult(roc(m3,1,%),10)
res:=HHV(GT(trixDay,AREF(trixDay,1)),2)
pahlson:=mult(res,10)
i30(pahlson)

Tacksam för svar...

[lfm]

Trix-grafen har bara automatisk skalning. Annars precis som angivet script.

Om jag sedan förstår vad du är ute efter så kan du testa kursändring sedan trans på detta sätt:

lastbuy:=LastTrade(B,p)
isbuyup:=gt(c,add(lastbuy,1))
isbuydn:=lt(c,sub(lastbuy,1))

lastsell:=LastTrade(S,p)
issellup:=gt(c,add(lastsell,1))
isselldn:=lt(c,sub(lastsell,1))

Men den principen går ju inte att backtesta förståss.

Eller är det något annat du menar?

[jorgeng]

Det verkar bra.

Hur blir då ex köpscriptet?:

period:=10
m1:=mov(C,period,e)
m2:=mov(m1,period,e)
m3:=mov(m2,period,e)
trixDay:=mult(roc(m3,1,%),10)
res:=HHV(GT(trixDay,AREF(trixDay,1)),2)
pahlson:=mult(res,10)
lastsell:=LastTrade(S,p)
issellup:=gt(c,add(lastsell,1))
i30(pahlson,issellup)

Om ex last trade var sälj på 670, skall scriptet ej köpa om kursen nu är 670, 670.5, 671, men däremot på 671 och över om köpscriptet i trix utlöses.

Kommer scriptet att fungera som det är skrivet nu vid i30?

[lfm]

Gör sista raden så här:

i30(And(pahlson,issellup))

om det är OCH-funktion du vill ha villkorat det med. Men någon funktion måste det vara.

Intradayprefixet är ingen funktion egentligen.

[jorgeng]

Tack lfm, skall testa när jag kommer hem.

[jorgeng]

hej lfm, jag får kompileringsfel på scriptet:

period:=10
m1:=mov(C,period,e)
m2:=mov(m1,period,e)
m3:=mov(m2,period,e)
trixDay:=mult(roc(m3,1,%),10)
res:=HHV(GT(trixDay,AREF(trixDay,1)),2)
pahlson:=mult(res,10)
lastsell:=LastTrade(S,p)
issellup:=gt(c,add(lastsell,1))
i30(And(pahlson,issellup))

Vad kan vara fel?

[lfm]

Om du ser i syntaxkontrollen så står det att högsta parentesdjup är 11 av tillåtna 10.

Men det finns en funktion som inte behövs egentligen och det är

ppahlsson:=Mult(xxx,10)

Det är ju bara för att bestämma höjd på flaggorna när detta är sista villkoret. Där har det ingen funktion nu.

Används 'res' direkt i sista And() istället.

Annars använd minnesreferenser för att komma förbi 10 parentesnivåer. Då kan du har 10 nivåer fram till varje referens du gör(sista raderna med enbart likhetstecken):

period:=10
m1:=mov(C,period,e)
m2:=mov(m1,period,e)
m3:=mov(m2,period,e)
trixDay:=mult(roc(m3,1,%),10)
lastsell:=LastTrade(S,p)
issellup:=gt(c,add(lastsell,1))
i30(
res=HHV(GT(trixDay,AREF(trixDay,1)),2)
pahlson=mult(res,10)
And(pahlson,issellup)
)

Nu tar det bara max 9 nivåer istället för 11.

Kom ihåg att intraday prefix måste börja innan minnesreferenserna(enkla likhetstecken) börjar.

Och sedan får inte tilldelade namn med := förekomma inom intradayprefixet.

Tar du sedan bort raden som inte behövs är du nere i 8:

period:=10
m1:=mov(C,period,e)
m2:=mov(m1,period,e)
m3:=mov(m2,period,e)
trixDay:=mult(roc(m3,1,%),10)
lastsell:=LastTrade(S,p)
issellup:=gt(c,add(lastsell,1))
i30(
res=HHV(GT(trixDay,AREF(trixDay,1)),2)
And(res,issellup)
)

Vill du skala flaggorna till 10% höjd så kör du mult() också på sista raden. Och väljer skala 0-100.

period:=10
m1:=mov(C,period,e)
m2:=mov(m1,period,e)
m3:=mov(m2,period,e)
trixDay:=mult(roc(m3,1,%),10)
lastsell:=LastTrade(S,p)
issellup:=gt(c,add(lastsell,1))
i30(
res=HHV(GT(trixDay,AREF(trixDay,1)),2)
Mult(And(res,issellup),10)
)