Scriptexempel

[Bertil]

Vi har ju renodlat trådarna lite med "Hur går era affärer" för redovisning av skarpa affärer plus lite simuleringar.
"Trading filosofi" har fått en egen tråd och nu tänkte jag att det var dags att börja en tråd för scriptexempel. Många håller ju hårt i sina script antingen de fungerar bra eller mindre bra. Ofta är det ju inställningarna i sciptet, ordermodellen, som är tricket medan själva ordermodellen borde kunna delas ut som allmängods. Ordermodellerna kanske även måste justeras för att fungera för handel med terminer aktier eller råvaruderivat.

Det som kan vara intressant att först dela med sig av är triggerscript. Vad är det för anomali eller rörelse som sätter igång triggen?
Vi kan ju trigga på:

1) Kursnivå
2) Kursrörelse (trend, break out)
3) Volymsändring
4) Tid. Kan vara tid på dagen, tid sedan senaste avslut, tid i månaden, tid på året osv.
5) Rörelser i andra instrument som förmedlas via cmpref.
6) Kombinationer av ovanstående.

Med kurs menas både close, open, högsta, lägsta, köp och säljkurser.
Kommer ni på fler triggparametrar så fyll bara på i tråden.

Ikväll tänkte jag bidra med en trigg som använder både kursändring och volymändring i kombination.
Tills dess så länkar jag till en annan variant som är en hemmagjord volymprofil.
http://www.autostock.se/vbulletin/sh...postcount=1776

Min målsättning med denna tråd är ju att vi skall kunna testa varandras script och komma med synpunkter och förbättringsförslag.
Som bekant så kör jag många ordermodeller parallellt så ett triggerscript betyder ju inte att det är en komplett strategi utan enbart att det är ett script som detekterar ett speciellt fenomen som man kanske är intresserad av.

mvh
Bertil

[Bertil]

Här är min Dynamiska Take Profit.
http://www.autostock.se/vbulletin/sh...postcount=1887
Edit: TP:n är inställd för terminshandel i punkter. Önskar man handla aktier så är det lämpligt att göra om gränserna till % av senaste closekurs.
mvh
Bertil

[Bertil]

Teorin bakom volymprofil säger ju att vid vissa nivåer uppfattas som mer "korrekta" dvs säljare och köpare tycker båda att kursen är korrekt varpå volymen ökar.
Jag är ute efter att detektera en rörelse då kursen rör sig från ett sådant område, dvs kursändringen sker med minskad volym. Först medelvärdesbildar jag produkten av kursen och volymen. Sedan dividerar jag med den medelvärdesbildade volymen. Jämför sedan med motsvarande medelvärde av kursen där inte volymen är inblandad. Kontroller även med medelvärden att kursrörelsen går åt rätt håll.
Ett sådant köpscript kan se ut så här:
{ volymprofil köp }

längd01:=20
steg01:=0.07
steg02:=0.1

i1(
hugo=Mov(mult(c,v),längd01,e)
sliten=Mov(v,längd01,e)
kvot=Div(hugo,sliten)
mv01=Mov(c,längd01,e)
diff=mult(div(Sub(mv01,kvot),c),1000)
mv1=linreg(c,25)
lutning01=Mult(Div(Sub(mv1,aref(mv1,1)),mv1),1000)
lutning02=Mult(Div(Sub(mv01,aref(mv01,1)),mv1),1000)
Draw(kvot,2,dgqb0)
Draw(mv01,3,mqb0)
villkor01=gt(diff,steg01)
köpa=And(And(villkor01,gt(lutning01,steg02)),gt(lutning02,steg02))
mult(köpa,20)
)
------------------------------------------------------------------------------
{ volymprofil sälj }

längd01:=20
steg01:=0.4
steg02:=-0.2
i1(
hugo=Mov(mult(c,v),längd01,e)
sliten=Mov(v,längd01,e)
kvot=Div(hugo,sliten)
mv01=Mov(c,längd01,e)
diff=mult(div(Sub(mv01,kvot),c),1000)
mv1=linreg(c,25)
lutning01=Mult(Div(Sub(mv1,aref(mv1,1)),mv1),1000)
lutning02=Mult(Div(Sub(mv01,aref(mv01,1)),mv1),1000)
Draw(kvot,2,dgqb0)
Draw(mv01,3,mqb0)
villkor01=gt(diff,steg01)
sälja=And(And(villkor01,lt(lutning01,steg02)),lt(lutning02,steg02))
mult(sälja,20)
)

[Rikard Nilsson]

Snyggt! Har du simulerat detta?

[Bertil]

Snyggt! Har du simulerat detta?

Kör man ordermodellerna enligt ovan så är de inte heltäckande dvs måste kombineras med andra ordermodeller.

Har bara simulerat tillsammans med mina 70+ andra ordermodeller. Då ökas vinsten något, men jag har inte börjat att köra skarpt ännu.

Då man kombinerar flera ordermodeller måste alla har ungefär samma handelstempo, annars så fungerar det inte. Inställningarna ändrar ju handelstempo så att de fungerar bra med andra ordermodeller.

mvh
Bertil

[Bertil]

Postade i annan tråd TP/SL aktiverad av tid.
se:
http://www.autostock.se/vbulletin/sh...postcount=2255
mvh
Bertil

[Bertil]

Helg igen! Istället för att filosofera tar jag och publicerar ett script!
Om man har ordermodeller som triggar på break out så händer det ibland att man handlar precis på övre bollingerbandet och kursen istället går ner. Då får man vända kappan efter vinden och byta position. Ett sådant script kan se ut så här:

{ Mitt Felstuds1 sälj vänd }
{ 150611 }
innehav:=Portfolio(v)
ok_att_handla:=Gt(innehav,0)
antal01:=80
förlust:=1
tidspärr1:=1
tidspärr2:=1
Lastbuy:=LastTrade(B,P)
lt1:=LastTrade(B,D)
lt2:=Portfolio(D)
minSedanKöp:=Mult(Sub(Date(),lt1),1440)
minSedanTrans:=Mult(Sub(Date(),lt2),1440)
delay_ok:=gt(minSedanKöp,tidspärr1)
trans_ok:=gt(minSedanTrans,tidspärr2)

i1(
tid1=gt(int(mult(frac(d),1440)),540)
{ före kl 17.00 }
tid2=lt(int(mult(frac(d),1440)),1020)

{ Analysen görs 9 minuter efter köp }
tid3=eqv(int(minSedanKöp),9)

{ Enkelt spikfilter för volymen }
val=if(gt(v,0),v,aref(v,1))
{ Se om volymen drar upp eller ner }
linje01=div(ema(mult(c,val),antal01),ema(val,antal01))
linje02=ema(c,antal01)
draw(linje01,1,rqb0)
draw(linje02,2,gqb0)

{ Kurvor för att detektera kortkorta trenden }
kurva01=mov(c,5)
kurva02=Aref(kurva01,1)

{ Detektera högsta kursen sedan köp }
stor=HHV(h,10)

{ Kursen har inte gått över köpkurs + 0,1 punkter de senaste 10 minutrarna }
villkor01=Le(stor,add(lastbuy,0.1))

{ Volymen skall dra ner något men inte för mycket för då kan vi ha en rekyl }
villkor02=And(Gt(sub(linje02,linje01),0.2),Lt(sub(linje02,linje01),4.2))

{ Vi måste ha förlust }
villkor03=Gt(Sub(lastbuy,c),förlust)

{ Kortkorta trenden måste vara ner }
villkor04=Gt(kurva02,kurva01)

sälja=And(And(And(And(villkor01,tid3),villkor02),villkor03),villkor04)

{ Ett annat spikfilter }
villkor80=And(And(Ge(s,sub(c,0.25)),Le(b,add(c,0.25))),Not(eqv(b,s)))
ditt_säljscript=And(And(And(And(And(sälja,tid1),tid2),delay_ok),trans_ok),villkor80)
säljsignal=And(And(ditt_säljscript,sälja),ok_att_handla)
Mult(säljsignal,10)
)

Med vänlig hälsning
Bertil


Edit: Villkor04 är kanske inte helt nödvändigt, jag har inte med det i min skarpa ordermodell. För mig som dagligen (3 dar i veckan ) handlar med Break out går ovanstående script in 3 gånger per halvår, 2 av gångerna med önskat resultat och en gång med oönskat. Eftersom scriptet triggar så sällan så kommer det att finnas ett visst inslag av curvefitting då man optimerar.

[Bertil]

Dålig aktivitet på forumet denna helg. Får väl publicera ett script till!

Detta är ett va) script som vänder sig till er som handlar terminer och vill simulera flera terminer i följd. Tipstack till Henrik för idén. Alla script som handlar från 0 innehav måste vara anslutna till scriptet. Då man vänder innehavet dvs går från +x till -x i antal har jag ett annat va) script. (Se Edit1)
Man kan simulera max från OMXS304F till OMXS305E. Börja att simulera bara för ett par terminer som väljs in enligt bifogad fil. Ange korrekt start och slutdatum. Observera att då man simulerar med flera terminer samtidigt så beräknas alla hela tiden även om de inte är aktiva. Dvs denna metod tar x gånger längre tid att simulera där x är antalet terminer som ingår jämfört med att manuellt simulera en termin i taget i följd.

range:=12
i1(
köpantal=Add(0,1)
innehav=Portfolio(v)
övermål=Ge(innehav,köpantal)
slutantal1=If(övermål,0,SUB(köpantal,innehav))
{ Önskas ackumulerad effekt sätt simulerakontot på 100000 och använd nedanstående slutantal1 }
{ slutantal1=Mult(MN(Int(Mult(Div(cash(n),mult(c,8.57)),0.9)),2500),100) }
O4FB=Ge(date(),2456794)
O4FE=Lt(date(),2456826)
O4GB=Ge(date(),2456826)
O4GE=Lt(date(),2456856)
O4HB=Ge(date(),2456856)
O4HE=Lt(date(),2456888)
O4IB=Ge(date(),2456888)
O4IE=Lt(date(),2456919)
O4JB=Ge(date(),2456919)
O4JE=Lt(date(),2456947)
O4KB=Ge(date(),2456947)
O4KE=Lt(date(),2456982)
O4LB=Ge(date(),2456982)
O4LE=Lt(date(),2457010)
O5AB=Ge(date(),2457010)
O5AE=Lt(date(),2457038)
O5BB=Ge(date(),2457038)
O5BE=Lt(date(),2457073)
O5CB=Ge(date(),2457073)
O5CE=Lt(date(),2457101)
O5DB=Ge(date(),2457101)
O5DE=Lt(date(),2457128)
O5EB=Ge(date(),2457128)
O5EE=Lt(date(),2457156)
O5FB=Ge(date(),2457156)
O5FE=Lt(date(),2457192)
O5GB=Ge(date(),2457192)
O5GE=Lt(date(),2457221)
O5HB=Ge(date(),2457221)
O5HE=Lt(date(),2457254)
O5IB=Ge(date(),2457254)
O5IE=Lt(date(),2457283)
O5JB=Ge(date(),2457283)
O5JE=Lt(date(),2457320)

villkor4F=And(And(O4FB,O4FE),eqv(crcid(),1391064143))
villkor4G=And(And(O4GB,O4GE),eqv(crcid(),1395367544))
villkor4H=And(And(O4HB,O4HE),eqv(crcid(),1484249413))
villkor4I=And(And(O4IB,O4IE),eqv(crcid(),1505080178))
villkor4J=And(And(O4JB,O4JE),eqv(crcid(),1542655275))
villkor4K=And(And(O4KB,O4KE),eqv(crcid(),1513187100))
villkor4L=And(And(O4LB,O4LE),eqv(crcid(),1602122137))
villkor5A=And(And(O5AB,O5AE),eqv(crcid(),4011492783))
villkor5B=And(And(O5BB,O5BE),eqv(crcid(),3982244854))
villkor5C=And(And(O5CB,O5CE),eqv(crcid(),3969798593))
villkor5D=And(And(O5DB,O5DE),eqv(crcid(),3922806596))
villkor5E=And(And(O5EB,O5EE),eqv(crcid(),3893570931))
villkor5F=And(And(O5FB,O5FE),eqv(crcid(),3931476778))
villkor5G=And(And(O5GB,O5GE),eqv(crcid(),3952605469))
villkor5H=And(And(O5HB,O5HE),eqv(crcid(),3771448864))
villkor5I=And(And(O5IB,O5IE),eqv(crcid(),3775517719))
villkor5J=And(And(O5JB,O5JE),eqv(crcid(),3813632590))

villkor92=And(Gt(Sub(Mx(cmpref(H,2,a),cmpref(H,1,a)),MN(cmpref(L,2,a),cmpref(L,1,a))),35),or(EQV(DayOfWeek(),1),EQV(DayOfWeek(),5)))
villkor93=And(Gt(Sub(Mx(cmpref(H,3,a),cmpref(H,2,a)),MN(cmpref(L,3,a),cmpref(L,2,a))),35),or(EQV(DayOfWeek(),1),EQV(DayOfWeek(),5)))
villkor95=And(0,1)
villkor96=Or(Gt(Sub(cmpref(h,2,a),cmpref(l,2,a)),range),Gt(Sub(cmpref(h,2,a),cmpref(l,2,a)),range))
villkor97=If(villkor95,villkor96,1)
villkor98=Or(Not(or(EQV(DayOfWeek(),1),EQV(DayOfWeek(),5))),and(villkor92,villkor93))
villkor99=or(or(or(or(or(or(or(or(villkor4I,villkor4H),villkor4G),villkor4F),villkor5D),villkor5E),villkor5F),villkor5G),villkor5H)
villkor02=or(or(or(or(or(or(or(or(villkor4L,villkor5A),villkor5B),villkor5C),villkor4K),villkor4J),villkor99),villkor5I),villkor5J)
slutantal2=if(And(And(villkor02,villkor02),villkor97),slutantal1,0)
slutantal2
)

{@A(0,OMX Stock )}

Med vänlig hälsning
Bertil


Edit2: Ovanstående script kräver att man inte äger några terminer vid terminsövergång. Jag själv går ju ur marknaden varje dag. Om man inte gör det så måste man tillverka en ordermodell som säljer av allt innehav sista dagen man handlar terminen.


Edit1: Antalsscriptet för att bara vända innehavet ser ut så här:

{Vända innehav}
innehav:=Portfolio(v)
i1(
slutantal=Mult(2,ABS(innehav))
slutantal
)

[Bertil]

Ett litet förtydligande. Jag har nämnt det förut, men här kommer reprisen:

Jag har alltid dubbla ordermodeller för varje triggerscript. Detta innebär då att jag har dubbla triggerscript ett "köp från noll innehav" och ett "köp vänd från negativt innehav". Om man gör på detta sätt är det mycket enkelt att i varje triggerscript lägga tidsvillkor när man får handla både för tid på dagen och tid efter senaste handel.

Med vänlig hälsning
Bertil

[e-Rik]

Tack för att du delar med dig Bertil. Vi som är på detta forumet delar ju samma mål och samma problem. Sedan är ju bara vägarna vi väljer lite olika.

Jag och min kompanjon försöker utveckla en modell som är trygg att köra igång men som ändå ger hyffsat med avkastning över tid. Vi låter modellen vänta på bra edge och går in när det inträffar, går det åt rätt håll så bygger vi på positionen går det åt fel håll så drar vi handbromsen.

Vi har just nu inriktat oss på affärer som sträcker sig från några dagar till max två veckor ungefär och det kan ibland vara långt mellan affärerna. På detta viset blir vårt enda jobb att byta termin och räkna om maxantalet en gång i månaden - i övrigt kan vi jobba vidare med våra "vanliga" jobb. Man borde ju kunna hitta någon bra trygg edge som infinner sig intradag och lämpar sig för daytrading. I vårt tänk behöver det ju inte hända så ofta. Händer det 20ggr per år och man vinner i snitt 4 punkter per gång så ger det 80 punkter. Kör du ett maxantal terminer som är baserat på antal kronor på depån dividerat med 20 000kr så ger det en avkastning på 40% vilket är ruggigt bra över tid med ränta på ränta effekten. Så de saker vi letar efter behöver inte hända så ofta, utan hellre att de är så säkra som möjligt för att minimera antalet förlustaffärer. Jag är rädd om man som du har en ganska aktiv daytradande modell att du får många små minusaffärer som äter upp dina vinster. Men så mycket som du jobbar med detta så har du ju säkert simulerat med att plocka bort de delar som ger många affärer men inte så många vunna punkter?

Mvh

Erik Ohlsson

[Bertil]

Hej Erik!
Jag har ju också varit inne på att försöka hitta små säkra vinster. Problemet är ju att kurserna rör sig en vanlig dag +-10 punkter samt att öppningskursen kan skilja sig från stängningskursen +-10 punkter.
En rörelse på 4 punkter kan ibland ske på några minuter utan att man fattar varför.

Har man en modell som triggar sällan måste man ha vettiga Take Profit och Stop Loss script. Om man däremot har en modell som triggar oftare (som jag ) så behöver man ingen SL utan blir räddad av trigg åt andra hållet. TP kan dock vara bra att ha ibland.

Hoppas du hittar en bra edge. Vore kul om du kunde dela med dig av lite simuleringar då du hittat något vinstgivande.
Med vänlig hälsning
Bertil


Edit1: En snittvinst på 4 punkter kan innebära 10 affärer med +18 punkters vinst och 10 affärer med -10 punkter. Kan också innebära 5 affärer med 46 punkters vinst och 15 med -10 punkter. Eller 15 affärer med 6 punkter vinst och 5 affärer med -2 punkter. Man måste först bestämma sig för vilken range som vinst och förlust får ligga inom, sedan får man trimma edgen.

[e-Rik]

Fast de dagarna rörelsen kommer utan att man fattar varför kanske man ska acceptera att inte göra några affärer. Uppstår inte "edge-situationen" så görs inga affärer. Det är nog bara om man är aktiv och följer börsen dagligen som man blir frustrerad om inga affärer görs. Är man mindre aktiv och bara kollar till det ibland så är man ju nöjd att affär kanske görs en gång i veckan eller ännu mer sällan - bara den är bra.

Är sugen på att börja titta på intradagshandel för att lägga till en dimension till på den modell jag utvecklar. Kan ju vara så att om min "längre" modell ligger positionerad för uppgång så letar intradagsmodellen efter situationer att gå in med ytterligare några positioner på kort sikt under dagen när situationer ges för att få ut ytterligare lite till från de uppgångar jag redan identifierat. Frågan är bara vad man ska kolla efter och i vilket upplösning. Skiljer ju en hel del i tekniska signaler mellan olika upplösningar.

/Erik

[Bertil]

Jo upplösning och handelsfrekvens hänger ju ihop. Det viktiga är ju att man själv känner sig bekväm med strategins handelsfrekvens. Innan man helt litar på sin modell så är det svårt att inte titta till resultatet flera gånger per dag. Menar du att du skall släppa iväg dina ordermodeller skarpt och sedan bara titta efter på lördag om den handlat något under veckan och i så fall kolla vad resultatet blev?

Med vänlig hälsning
Bertil

[e-Rik]

Nja. Alltså först måste den ju testas. Jag har precis fått igång den på en VPS kopplad mot testkonto. Sedan är meningen att sms för avsluten ska räcka. Ungefär som att köpa fonder eller hyra en modell. Ju mer jag följer börsutvecklingen desto mer sugen blir jag på att gå in och knappa eller få till en modell som gör betydligt fler affärer bara för att inte riskera att gå miste om fina rörelser. Men av vad jag har testat så vore det bättre att låtit bli många av dessa tillfällena och bara gå in när det verkligen visar sig en skarp edge och sedan sätter man en vettig stopp på den så ifall det inte drar på det håll man trodde så är det bara att stiga av med en mindre förlust och vänta på nästa tillfälle. /Erik

[Bertil]

Tycker fortfarande att det publiceras för lite script. Här är en av mina 35 ordermodeller som handlar skarpt just nu. Kommentarerna är inlagda för forumets skull. Jag har ju tidigare jämfört OMXS30 med DAX för att få bättre trender. Väldigt snabba minitrender på ett par minuter kan man få genom att studera DAX. Dock är det så att vissa dagar så följer OMXS30 direkt efter DAX och vissa dagar går S30 sin egen väg. Vilka fenomen som styr detta verkar vara komplext och jag har inte lyckats att reda ut detta.

Men vi har ju OMXSPI som innehåller många fler aktier än S30 och därmed är lite stabilare vad gäller att detektera halvlånga trender (som i min värld varar 30-120 minuter).
För överföring av gårdagens closekurs via cmpref använder jag minutdata eftersom jag inte vill offra en av mina cmpref till dagsdata.

.........................
{ Mitt BolS2 köp }
{ 150929 }
innehav:=Portfolio(v)
ok_att_handla:=eqv(innehav,0)
{ Jag har en snarlik ordermodell för villkoret då jag innehar negativ position }

{ Nedanstående tidsspärrar är för att inte för snart gå in i marknaden igen då jag är utanför }
tidspärr1:=450
tidspärr2:=450
lt1:=LastTrade(S,D)
lt2:=LastTrade(B,D)
minSedanSälj:=Mult(Sub(Date(),lt1),1440)
minSedanKöp:=Mult(Sub(Date(),lt2),1440)
delay_ok:=gt(minSedanSälj,tidspärr1)
trans_ok:=gt(minSedanKöp,tidspärr2)

i1(
{ efter kl 09.15 }
tid1=gt(int(mult(frac(d),1440)),555)
{ före kl 17.05 }
tid2=lt(int(mult(frac(d),1440)),1025)

{ Denna parameter räknar perioder bakåt till dagens open }
perioder01=Sub(int(mult(frac(d),1440)),540)

{ Gårdagens close för terminen beräknas utifrån minutdata }
igårcloseTerm=aref(c,add(perioder01,2):600)

{ Gårdagens close för OMXS30 beräknas utifrån minutdata }
igårcloseS30=cmpref(c,add(perioder01,2):600,a)

{ Gårdagens close för OMXSPI beräknas utifrån minutdata }
igårcloseSPI=cmpref(c,add(perioder01,2):600,b)

{ OMXS30 justeras till samma storlek/värde som terminen }
S30nu=div(mult(cmpref(c,0,a),igårcloseTerm),igårcloseS30)

{ OMXSPI justeras till samma storlek/värde som terminen }
SPInu=div(mult(cmpref(c,0,b),igårcloseTerm),igårcloseSPI)

{ Absolutskillnaden mellan S30 och SPI för de senaste 10 min beräknas }
diffSPIS30=abs(sub(mov(SPInu,10),mov(S30nu,10)))

kurva01=mov(c,10)

{ OMXS30 måste ligga minst 1.2 punkter över OMXSPI }
villkor01=Gt(sub(mov(S30nu,10),mov(SPInu,10)),1.2)

{ Terminen måste ligga minst 0.2 punkter över OMXS30 }
villkor02=Gt(sub(c,S30nu),0.2)

{ kurva01 måste vara stigande }
villkor03=Lt(Div(Sub(aref(kurva01,1),kurva01),kurva01),-0.0001)

{ Skillnaden mellan SPI och S30 måste öka }
villkor04=Gt(diffSPIS30,aref(diffSPIS30,1))
{ villkor04 sparas i global variabel ifall andra script vill titta på detta värde }
SetGVarIf(villkor04,110,1,T)

Draw(SPInu,2,dgqb0)
Draw(S30nu,3,rqb0)
Draw(igårcloseTerm,4,bqb0)

{ Nedan följer lite villkor för att ej handla på måndagar och fredagar förutom vid stor volatilitet }
villkor92=And(Gt(Sub(Mx(cmpref(H,2,c),cmpref(H,1,c)),MN(cmpref(L,2,c),cmpref(L,1,c))),35),or(EQV(DayOfWeek(),1),EQV(DayOfWeek(),5)))
villkor93=And(Gt(Sub(Mx(cmpref(H,3,c),cmpref(H,2,c)),MN(cmpref(L,3,c),cmpref(L,2,c))),35),or(EQV(DayOfWeek(),1),EQV(DayOfWeek(),5)))
villkor98=Or(Not(or(EQV(DayOfWeek(),1),EQV(DayOfWeek(),5))),or(And(villkor92,villkor93),and(EQV(DayOfWeek(),5),or(villkor92,villkor92))))

köpa=And(And(And(And(villkor01,villkor02),villkor03),villkor04),villkor98)
ditt_köpscript=And(And(And(And(köpa,tid1),tid2),delay_ok),trans_ok)
köpsignal=And(ditt_köpscript,ok_att_handla)
Mult(köpsignal,10)
)

{@A(1,OMX Stock )@B(1,SX All-Sha)@C(0,OMX Stock )}

......................................

Frågor på det?

Med vänlig hälsning
Bertil