Raptor

[BRB_67]

Borde du fått nu om du inte gjort några trades tidigare idag, annars spärrar villkoret "ej_idag". Jag provade att koppla bort det och fick grön signal direkt nu.



Nice!

Blev inget mer (som tur var), mfi hann nog över 85 sen försvann signalen för h>h

Konstig nog försökte den inte långa på slutet heller, de två sista staplarna ser ju rätt så "long" ut med alla villkor uppfyllda + inga trades innan

[Rikard Nilsson]

Jag ska se om jag hinner modifiera scripten lite och förenkla villkoret för MFI, tanken är att endast mäta lutningen för MFI i föregående stapel. De simuleringar jag gjort tyder på bra resultat så länge man låter den stänga på MFI > 99.

[BRB_67]

Ops!
Fel i scriptet, skall vara en nolla på slutet därför longar den inte.

{Raptor long }
{ 120316 }

{ definiera variabler }
mval:=mov(mfi(3),3,e)
triglevel:=hhv(aref(mval,1),2)

{ definiera gränsvärde för MFI och testa om innehav finns }
condition1:=lt(mval,85)
innehav_ok:=eqv(portfolio(v),1)
mcd_signal:=gt(macd(n),macd(t))

[Rikard Nilsson]

Senaste scriptversioner från vår sida nedan. Det som är ändrat är att MFI-kurvans lutning nu mäts snarare än att testa om den skurit sin triggnivå. Mätning görs på föregående stapels slutvärde, dvs MFI-villkoret består under hela innevarande stapel. Däremot testas stigande/fallande High/Low i realtid mot förra stapeln, så signal kan lösa ut när som helst i en stapel.

Vi behåller tillsvidare begränsning på antal trades per dag. Scripten nedan ligger bara här på forumet tills vi uppdaterar "officiellt".


{Raptor long }
{ 120319 }

{ definiera variabler }
mval:=mov(mfi(3),3,e)
mcd_signal:=gt(macd(n),macd(t))

{ definiera gränsvärde för MFI och testa om innehav finns }
condition1:=lt(mval,90)
innehav_ok:=le(portfolio(v),0)

{ säkerställ att säljtransaktion inte skett idag }
ej_idag:=gt(int(d),int(lasttrade(s,d)))

{ säkerställ att det är minst 6 minuter kvar till börsstängning }
öppet:=ge(mult(1440,sub(market(c),frac(date()))),6)

{ säkerställ att klockan är minst 09:06 }
inpådagen:=Gt(Frac(date()),0.379)

{ feedback loop för att köpa tillbaka eventuellt blankat överskott }
överexponerad_short:=lt(portfolio(v),scrpar(23))

{ spärr som hindrar orderläggning 1 minut efter senaste order }
timelock:=1
lt1:=LastTrade(B,D)
lt2:=LastTrade(S,D)
minSedanKöp:=mult(sub(date(),lt1),1440)
minSedanSälj:=mult(sub(date(),lt2),1440)
i30(
{ account safety - säkerställer kontakt med depån }
orderdelay_ok=and(gt(minSedanKöp,timelock),gt(minSedanSälj,timelock))
datum_ok=eqv(int(d),int(date()))

{ rita upp MFI-kurva i volymområdet }
draw(mval,2,dysv)

{ trading-regler - MFI stigande samt condition1 = MFI < 90 }
buy1=and(condition1,gt(aref(mval,1),aref(mval,2)))

{ villkor att innehav inte finns }
buy2=and(buy1,innehav_ok)

{ villkor att stapel ska nå högre än föregående stapel }
buy3=and(buy2,gt(h,aref(h,1)))

{ koppla ihop villkor }
buy4=and(and(or(överexponerad_short,and(buy3,or(lt(portfolio(v),0),ej_idag))),öppet),orderdelay_ok)
buy5=and(and(buy4,datum_ok),inpådagen)
buy6=and(buy5,mcd_signal)
mult(buy6,10)
)




{Raptor short }
{ 120319 }

{ definiera variabler }
mval:=mov(mfi(3),3,e)
mcd_signal:=lt(macd(n),macd(t))

{ definiera gränsvärde för MFI och testa om innehav finns }
condition1:=gt(mval,10)
innehav_ok:=ge(portfolio(v),0)

{ säkerställ att köptransaktion inte skett idag }
ej_idag:=gt(int(d),int(lasttrade(b,d)))

{ säkerställ att det är minst 6 minuter kvar till börsstängning }
öppet:=ge(mult(1440,sub(market(c),frac(date()))),6)

{ säkerställ att klockan är minst 09:06 }
inpådagen:=Gt(Frac(date()),0.379)


{ feedback loop för att köpa tillbaka eventuellt köpt överskott }
överexponerad_long:=gt(portfolio(v),scrpar(22))
timelock:=1

{ spärr som hindrar orderläggning 1 minut efter senaste order }
lt1:=LastTrade(B,D)
lt2:=LastTrade(S,D)
minSedanKöp:=mult(sub(date(),lt1),1440)
minSedanSälj:=mult(sub(date(),lt2),1440)
i30(
{ account safety - säkerställer kontakt med depån }
orderdelay_ok=and(gt(minSedanKöp,timelock),gt(minSedanSälj,timelock))
datum_ok=eqv(int(d),int(date()))

{ trading-regler - MFI fallande samt condition1 = MFI > 10 }
short1=and(condition1,lt(aref(mval,1),aref(mval,2)))

{ villkor att innehav inte finns }
short2=and(short1,innehav_ok)

{ villkor att stapel ska nå lägre än föregående stapel }
short3=and(short2,lt(l,aref(l,1)))

{ koppla ihop villkor }
short4=and(and(or(överexponerad_long,and(short3,or(gt(portfolio(v),0),ej_idag))),öppet),orderdelay_ok)
short5=and(and(short4,datum_ok),inpådagen)
short6=and(short5,mcd_signal)
mult(short6,10)
)




{Raptor exit long }
{ 120319 }

{ definiera variabler }
high:=cmpref(h,1,a)
low:=cmpref(l,1,a)
mval:=mov(mfi(3),3,e)
condition1:=gt(mval,99)

{ beräkna dagens takeprofit som 40% av gårdagens range - dock minst 0.75 pkt }
tplevel:=mx(mult(sub(high,low),0.4),0.75)
takeprofit:=gt(c,add(tplevel,lasttrade(b,p)))

{ säkerställ att innehav finns }
innehav_ok:=gt(portfolio(v),0)

{ säkerställ att det är minst 6 minuter kvar till börsstängning }
öppet:=ge(mult(1440,sub(market(c),frac(date()))),6)

{ säkerställ att databastid och systemtid är på samma dag }
datum_ok:=eqv(int(d),int(date()))

{ säkerställ att klockan är minst 09:01 }
inpådagen:=Gt(Frac(date()),0.376)

{ testa om vinst är minst 2 pkt }
vinst:=gt(c,add(lasttrade(b,p),2))
i30(
{ rita takeprofit-nivå som grönstreckad linje och senaste köpnivå som blå}
draw(add(lasttrade(b,p),tplevel),2,dgqb2)
draw(lasttrade(b,p),3,bqb)

{ koppla ihop villkor - takeprofit eller MFI > 99 eller 2 pkt vinst och MFI = fallande }
sell1=or(or(takeprofit,condition1),and(vinst,lt(aref(mval,1),aref(mval,2))))
sell2=and(and(and(and(sell1,datum_ok),inpådagen),innehav_ok),öppet)
mult(sell2,5)
)

{@A(0,)}






{Raptor exit short }
{ 120319 }

{ definiera variabler }
high:=cmpref(h,1,a)
low:=cmpref(l,1,a)
mval:=mov(mfi(3),3,e)
condition1:=lt(mval,1)

{ beräkna dagens takeprofit som 40% av gårdagens range - dock minst 0.75 pkt }
tplevel:=mx(mult(sub(high,low),0.4),0.75)
takeprofit:=lt(c,sub(lasttrade(s,p),tplevel))

{ säkerställ att innehav finns }
innehav_ok:=lt(portfolio(v),0)

{ säkerställ att det är minst 6 minuter kvar till börsstängning }
öppet:=ge(mult(1440,sub(market(c),frac(date()))),6)

{ säkerställ att databastid och systemtid är på samma dag }
datum_ok:=eqv(int(d),int(date()))

{ säkerställ att klockan är minst 09:01 }
inpådagen:=Gt(Frac(date()),0.376)

{ testa om vinst är minst 2 pkt }
vinst:=lt(c,sub(lasttrade(s,p),2))
i30(
{ rita takeprofit-nivå som magentastreckad linje och senaste blanknivå som röd}
draw(sub(lasttrade(s,p),tplevel),2,mqb2)
draw(lasttrade(s,p),3,rqb)

{ koppla ihop villkor - takeprofit eller MFI < 1 eller 2 pkt vinst och MFI = fallande }
cover1=or(or(takeprofit,condition1),and(vinst,gt(aref(mval,1),aref(mval,2))))
cover2=and(and(and(and(cover1,datum_ok),inpådagen),öppet),innehav_ok)
mult(cover2,5)
)

{@A(0,)}

[NickoTrader]

Vad får du för resultat på A, B och C-terminerna? De har väldigt olika karaktär så det skulle vara intressant.

[mikola]

Vad är det för nytt i exit-scripten?
Mvh
Mikael

[BRB_67]

Inga ordrar går igenom idag heller, extra kontrollscriptet larmar inte

09:30 ORDER "sl) OMX Raptor short OMXS302D" kurs 1089.00
09:30 ORDER "(xk) Mandatory account check spärrar order för OMXS302D" kurs
09:30 GSM larm sänt!

xxxxxxxxxxxx

09:40 ORDER "sl) OMX Raptor short OMXS302D" kurs 1088.00
09:40 ORDER "(xk) Mandatory account check spärrar order för OMXS302D" kurs
09:40 GSM larm sänt!

[Rikard Nilsson]

Hm, har du fått något larm från scriptet i sig?

Jag har lagt tillbaka en tidigare programversion om ni som kör .14 nu vill "nedgradera" ett steg.

[Berra]

Jag graderade ned programmet via "uppgradera program" och då gick ordern igenom direkt så det var något fel i .14

09:44 ORDER "sl) OMX Raptor short OMXS302D" kurs 1088.50

[BRB_67]

Ned-daterat nu
Nej inga larm fårn extrascriptet

Order direkt
09:51 ORDER "sl) OMX Raptor short OMXS302D" kurs 1089.25

[Rikard Nilsson]

Jo, något är galet. Skicka gärna hela Tradelog igen så får vi undersöka dagens uppstart med synkning etc av depån osv.

[JMillard81]

9.30: OMX Raptor Short OMXS302D kurs 1089.00

Kör med de script som postades här på forumet igår.

[Rikard Nilsson]

Men den stora frågan kvarstår, har ni fått några larm direkt från scriptet som kollar depåinfo? (obs endast ni som kör version .14)

[BRB_67]

Men den stora frågan kvarstår, har ni fått några larm direkt från scriptet som kollar depåinfo? (obs endast ni som kör version .14)

Nej, inga larm - har det kopplat och lokala larm ikryssat
Sökte genom larmlistan i wp++

[Berra]

Men den stora frågan kvarstår, har ni fått några larm direkt från scriptet som kollar depåinfo? (obs endast ni som kör version .14)

Nej inte här heller, och nu har jag backat.