Trading-filosofi

[Henric]

Det finns två sätt att tjäna pengar. Köpa billigt o sälja dyrt eller köpa dyrt o sälja dyrare (long). Dvs counter trend / mean reversion eller momentum.

Inga strategier fungerar hela tiden. Var beredd på lägre resultat än simulering. Marnadsklimat påverkar. Ändå svårt i övergångar.

[Bertil]

All aktiehandel föregås ju av någon typ av analys. I sin enklaste form så bygger handeln bara på en känsla i kombination med ett antagande, exempelvis: Trenden går starkt upp nu så det är bäst att haka på. Analysen bygger på att index gått stadigt upp ett tag och känslan säger att det bör fortsätta.
Här kommer då även in om man är optimistisk eller pessimistisk till sin läggning.

Slutsatsen kan också vara tvärt om: Nu har det gått upp så länge och allt är övervärderat så nu måste det snart gå ner.

Mer seriösa aktiehandlare läser ju årsbokslut och kvartalsrapporter, bedömer ledningens kompetens och branschens framtidsutsikter.
Om man specialiserat sig på en viss sektor så känner aktieägaren till Bioteknikbolagets produkter, vilka kliniska studier som är på gång och om/när ett godkännande från Läkemedelsverket/FDA är att vänta.
Gillar man mining läser man kartor över produktionsområdet och försöker att dra slutsatser utifrån detta.

Sedan måste man även ta hänsyn till Makro som ibland är helt avgörande för aktiekurserna. Med Makro menar jag energipris, räntenivåer, terroraktivitet, politisk oro (handelshinder, krig) mm.

Vad man än gör för att få en framförhållning så letar sig informationen till sist fram till aktiekursen.

Vi som använder NAT jobbar ju med teknisk analys så då är frågeställningen Hur skall vi analysera för att få en framförhållning och vilken är handelsfrekvensen som vi skall använda.

Som bekant har jag ju snöat in på att handla terminen då den bygger på OMXS30 och bara är beroende på hur det går för de 30 ingående aktierna. Statistiskt inbillar jag mig att detta blir robustare än att handla en enskild aktie, men samtidigt så blir man känsligare för makro.

Då jag handlar terminen analyserar jag:
Trender på terminens kurs (olika typer av medelvärdesbildningar).
Plötsliga kursändringar hos terminen (derivator på medelvärdesbildningar och olika typer av break out).
Analys av kurs och volym i olika typer av matematiska beräkningar.

Dessutom analyserar jag trenderna hos de i terminen ingående aktierna och även volymerna per aktie.
Index är ju summan av hur det går för de ingående aktierna men jag summerar även alla aktier som går nedåt och sätter i relation till alla aktier som går uppåt.

För att få in makro analyserar jag DAX indexet och har tagit fram en metod som ser på om terminen dras av en enskild aktie eller av DAX.

Nu senast har jag gjort script som analyserar alla 30 i DAX ingående aktier. Bara någon enstaka av dessa aktier finns lagrat hos kundtjänst så jag får avvakta med att göra analys tills jag samlat på mig mer aktiedata.

mvh
Bertil

[Bertil]

Tänkte publicera lite script på analys av de i DAX30 ingående aktierna.
Man får göra 10 ordermodeller. Nedan är den 10:e och sista ordermodellen där jag analyserar de 3 sista aktierna som cmpref plus gör sammanställningen.

De parametrar som heter kurva11 osv är egentligen ingen kurva utan den procentuella förändringen av aktiekursen för de 10 senaste minuterna.
bas1 osv är den indexvägda procentuella förändringen.
Nu lägger jag samman alla negativa förändringar i den globala variabeln 3941 och alla positiva förändringar i den globala variabeln 3943.
Sedan adderar jag absolutbeloppen av förändringarna.
I den globala parametern 3942 lägger jag den avvägda fördelningen mellan de bolag som drar index och de bolag som bromsar. 0 betyder att börsvärdesändringen av de bolag som handlas uppåt är lika stort som börsvärdesändringen av de bolag som handlas neråt. +1 betyder att alla bolag är med på uppgången och -1 att alla bolag är i nedgång.
OBS att detta godhetstal inte har något att göra med hur kraftig indexändringen är utan bara om hur stor andel av börsvärdet som följer trenden.
......................................................................

{ DDD3 28 to 30 }

i1(
vikt1=Div(1.05,100)
vikt2=Div(1.43,100)
vikt3=Div(2.57,100)

kurva11=Div(Sub(cmpref(c,0,a),cmpref(c,10,a)),cmpref(c,10,a))
kurva12=Div(Sub(cmpref(c,0,b),cmpref(c,10,b)),cmpref(c,10,b))
kurva13=Div(Sub(cmpref(c,0,c),cmpref(c,10,c)),cmpref(c,10,c))

bas1=Mult(kurva11,vikt1)
bas2=Mult(kurva12,vikt2)
bas3=Mult(kurva13,vikt3)

mas1=if(Lt(bas1,0),bas1,0)
mas2=if(Lt(bas2,0),bas2,0)
mas3=if(Lt(bas3,0),bas3,0)
mas4=add(add(mas1,mas2),mas3)
SetGVarIf(Add(GetGVar(3941),mas4),3941,1)

mas5=if(Gt(bas1,0),bas1,0)
mas6=if(Gt(bas2,0),bas2,0)
mas7=if(Gt(bas3,0),bas3,0)
mas8=add(add(mas5,mas6),mas7)
SetGVarIf(Add(GetGVar(3943),mas8),3943,1)

negativ01=Add(GetGVar(3941),0)
positiv01=Add(GetGVar(3943),0)
totalen01=Add(abs(positiv01),abs(negativ01))
tillfällig1=if(Gt(positiv01,abs(negativ01)),sub(div(positiv01,totalen01),0.5),add(div(negativ01,totalen01),0.5))
tillfällig2=mult(2,tillfällig1)
SetGVarIf(tillfällig2,3942,1)

kurva21=Div(Sub(cmpref(c,10,a),cmpref(c,20,a)),cmpref(c,20,a))
kurva22=Div(Sub(cmpref(c,10,b),cmpref(c,20,b)),cmpref(c,20,b))
kurva23=Div(Sub(cmpref(c,10,c),cmpref(c,20,c)),cmpref(c,20,c))

das1=Mult(kurva21,vikt1)
das2=Mult(kurva22,vikt2)
das3=Mult(kurva23,vikt3)

nas1=if(Lt(das1,0),das1,0)
nas2=if(Lt(das2,0),das2,0)
nas3=if(Lt(das3,0),das3,0)
nas4=add(add(nas1,nas2),nas3)
SetGVarIf(Add(GetGVar(3945),nas4),3945,1)

nas5=if(Gt(das1,0),das1,0)
nas6=if(Gt(das2,0),das2,0)
nas7=if(Gt(das3,0),das3,0)
nas8=add(add(nas5,nas6),nas7)
SetGVarIf(Add(GetGVar(3947),nas8),3947,1)

negativ02=Add(GetGVar(3945),0)
positiv02=Add(GetGVar(3947),0)
totalen02=Add(abs(positiv02),abs(negativ02))
tillfällig3=if(Gt(positiv02,abs(negativ02)),sub(div(positiv02,totalen02),0.5),add(div(negativ02,totalen02),0.5))
tillfällig4=mult(2,tillfällig3)
SetGVarIf(tillfällig4,3946,1)

ändring=Sub(tillfällig2,tillfällig4)
SetGVarIf(ändring,3948,1)

And(0,0)
)

{@A(1,TKA )@B(1,VNA )@C(1,VOW3 )}

.................................

mvh
Bertil

[Bertil]

kurva21 osv är motsvarade förändring, fast den som inträffade mellan 20 och 10 perioder bakåt.

Jag lägger på samma sätt som ovan denna förändring i den globala variabeln 3946.

Nu kommer vi till det intressanta. Om vi minskar den senaste förändringen (global 3942 med den tidigare förändringen 3946 och lägger resultatet i den globala parametern 3948 så får vi ett mått på förändringshastigheten.
Denna parameter visar alltså om det är mer eller mindre börskapitalvärde per tidsenhet som vill hänga med i trenden.
Denna sista parameter är inte riktigt samma sak som att bara titta på derivatan av index eftersom jag har normerat mina parametrar. Om alla bolag var upp på 3946 dvs +1 och alla bolag fortfarande är upp dvs +1 i 3942 så blir 3948=0 som betyder ingen förändring. Denna parameter har inget med derivatan på indexet att göra.

Som jag tidigare sa så drivs ju index av information och mitt försök ovan är att se om jag ur ovan beräknade information kan dra några slutsatser om kommande indexkurs. Nu tittar jag ju bara 20 minuter bakåt så predikteringen av kommande indexkurs kanske bara är giltig 20-60 minuter (perioder) framåt.

Jag har ju inte kunnat simulera detta ännu då jag började med kursinsamlingen i fredags.
Time will tell...

mvh
Bertil


Edit: Nu tror många att jag skall använda ovanstående för att handla DAX minisar, men det är inte tanken. Eftersom DAX påverkar OMXS30 så skall jag förstås använda informationen då jag handlar OMXS30 terminen, som vanligt.
Jag analyserar som sagt alla i OMXS30 ingående bolag på samma sätt som ovan också. Här har jag ju all historisk data, men har inte hunnit simulera ännu...

[Bertil]

Dessa aktier med tillhörande viktning ingår i DAX indexet
https://en.wikipedia.org/wiki/DAX
I en annan tråd ställdes frågan vad realtid tyska aktier kostar hos Nordnet.
Svar: Vet ej. Kan eventuellt bero på vilket avtal man har med Nordnet. Förra året hade jag realtid USA och det kostade 28:-/mån.
Så här ser scriptet ut för de 3 första aktierna i DAX.
----------------------------------------------------
{ DDD3 01 to 03 }

i1(

vikt1=Div(3.44,100)
vikt2=Div(7.84,100)
vikt3=Div(8.30,100)

SetGVarIf(0,3941,1)
SetGVarIf(0,3943,1)

kurva11=Div(Sub(cmpref(c,0,a),cmpref(c,10,a)),cmpref(c,10,a))
kurva12=Div(Sub(cmpref(c,0,b),cmpref(c,10,b)),cmpref(c,10,b))
kurva13=Div(Sub(cmpref(c,0,c),cmpref(c,10,c)),cmpref(c,10,c))

bas1=Mult(kurva11,vikt1)
bas2=Mult(kurva12,vikt2)
bas3=Mult(kurva13,vikt3)

mas1=if(Lt(bas1,0),bas1,0)
mas2=if(Lt(bas2,0),bas2,0)
mas3=if(Lt(bas3,0),bas3,0)
mas4=add(add(mas1,mas2),mas3)
SetGVarIf(Add(GetGVar(3941),mas4),3941,1)

mas5=if(Gt(bas1,0),bas1,0)
mas6=if(Gt(bas2,0),bas2,0)
mas7=if(Gt(bas3,0),bas3,0)
mas8=add(add(mas5,mas6),mas7)
SetGVarIf(Add(GetGVar(3943),mas8),3943,1)

SetGVarIf(0,3945,1)
SetGVarIf(0,3947,1)

kurva21=Div(Sub(cmpref(c,10,a),cmpref(c,20,a)),cmpref(c,20,a))
kurva22=Div(Sub(cmpref(c,10,b),cmpref(c,20,b)),cmpref(c,20,b))
kurva23=Div(Sub(cmpref(c,10,c),cmpref(c,20,c)),cmpref(c,20,c))

das1=Mult(kurva21,vikt1)
das2=Mult(kurva22,vikt2)
das3=Mult(kurva23,vikt3)

nas1=if(Lt(das1,0),das1,0)
nas2=if(Lt(das2,0),das2,0)
nas3=if(Lt(das3,0),das3,0)
nas4=add(add(nas1,nas2),nas3)
SetGVarIf(Add(GetGVar(3945),nas4),3945,1)

nas5=if(Gt(das1,0),das1,0)
nas6=if(Gt(das2,0),das2,0)
nas7=if(Gt(das3,0),das3,0)
nas8=add(add(nas5,nas6),nas7)
SetGVarIf(Add(GetGVar(3947),nas8),3947,1)

And(0,0)
)


{@A(1,ADS )@B(1,ALV )@C(1,BAS )}
................................................................................
Det är bara att lägga in övriga aktier i script/ordermodeller enligt ovan.

mvh
Bertil


Edit: OBS nollningen av de globala parametrar som innehåller summation görs ju förstås bara i den första ordermodellen enligt ovan. Man skall namnge ordermodellerna så att de körs efter varandra.

[Bertil]

Det är alltså lätt att göra egen analys på alla i index ingående aktier och sedan addera ihop resultatet. Vad man skall tänka på är att om man analyserar de ingående aktierna på samma sätt som man analyserar index så får man inte ut någon mer information utan det är bara slöseri med processorkraft.

Om man däremot tar med volymen då man analyserar individuella aktier tillför man ju information som inte kan extraheras ur indexet. Även varianter med ickelinjär analys på enskilda aktier kan tillföra information.

mvh
Bertil

[Bertil]

I scripten ovan tittade jag på hur stor andel av börsvärdet som följer trenden. Om man vill så kan man multiplicera med volymen och på liknande sätt få fram hur stor del av det aktivt handlade kapitalet som följer trenden. I så fall får man dela upp i 10 st 1 minutersintervall och se om kursen handlas upp eller ner i respektive 1 minutersintervall och addera uppvolym resp nervolym för sig. Detta blir lite trixigare och jag är osäker på om det ger mer information som är användbar för prediktering av indexkursen.
Jag har i och för sig gjort sådana script för OMXS30 terminshandeln men ibland så extraherar man ju bara ut samma information fast på flera olika sätt.

mvh
Bertil

[Bertil]

Förtydligande. Jag handlar inte direkt på dessa godhetstal utan jag använder dem i kombination med andra triggerscript för att verifiera dessa.

mvh
Bertil

[Bertil]

Dags för lite filosofiska grubblerier i sommarstormen.
I ett tidigare inlägg så ställde jag frågan: Hur lång är Sveriges kust?
Antag att vi har en högupplöst bild av Sverige och att vi med hjälp av en linjal (eller passare) skall beräkna kuststräckan. Vi kommer då att upptäcka att kustlängden beror på den upplösning vi väljer att mäta med! Antag att passaren ställs in att motsvara 10 km och vi stegar oss runt kuststräckan, då får vi ett värde. Ställer vi in en sträcka som motsvarar 1 km får vi ett högre värde. Med 100 m inställt får vi ytterligare en högre värde på kuststräckan osv.

På samma sätt förhåller det sig med upplösning på en indexkurva och hävstången på det instrument som man skall använda sig av.

Med en hävstång på 1 så är vissa hack (fenomen) i kurvan ointressanta och kan betraktas som brus. Med hävstången 15 däremot kan dessa hack användas som edgar.

Det är därför helt avgörande då man pratar om en strategi att samtidigt tala om vilken upplösning på kurvan man bör använda, vilken hävstång strategin är utformad för och vilken handelsfrekvensen blir.

Många missförstånd i detta forum beror på att vi blandar strategier som handlar en gång i kvartalet med strategier som gör avslut flera gånger per dag utan att tydligt tala om detta.

mvh
Bertil

[Bertil]

Låt oss nu komma in på handelsklimat.
För att definiera ett handelsklimat så är det också helt avgörande att man samtidigt talar om vilken upplösning som avses.
Om börsen huvudsakligen varit stigande under en 10-årsperiod så anger många att handelsklimatet varit positivt under denna tid.

I min daytradingstrategi så har jag scriptat att man inte skall handla på måndagar och fredagar eftersom handelsklimatet är annorlunda dessa dagar då de statistiskt inte innehåller så tydliga halvdagstrender. Jag har tolkat det så att det tar en dag att smälta de makrohändelser som inträffat under helgen och att marknaden är osäker på att prediktera de makrohändelser som kanske kommer att inträffa kommande helg.

mvh
Bertil

[Bertil]

Nu till ett annat kärt ämne, nämligen curvefitting.
Då man tar fram en strategi så optimerar man den på ett instrument (säg index) under en viss tidsperiod (in sample). Sedan testar men den på en annan tidsperiod (out of sample) för att verifiera att den fungerar.
Vad är det då som skiljer out of sample från in sample? Oftast är det handelsklimatet.
För att få en strategi robust bör den alltså fungera för olika handelsklimat. Hur gör man då detta?
1) Man måste definiera olika handelsklimat.
2) Man måste ta fram ordermodeller som passar för respektive handelsklimat.

Definitionen på detta handelsklimat är alltså hur det påverkar ordermodellen.
Antingen kan man definiera ett handelsklimat med en dummyordermodell och lägga värdet i en global cell för att aktivera vissa ordermodeller eller så kan man bygga in det i själva ordermodellen.
Man kan tex låta takeprofit vara beroende av Bollingerbanden om man nu önskar TP mellan Bollingerbanden.

mvh
Bertil

[Bertil]

Hur skulle då en helt adaptiv strategi se ur.

Antag att man gör 25 avslut under en viss tid X.
1) Optimera strategin för perioden X.
2) Gör 1) varje kväll, och mata in de optimerade variablerna.

Ovanstående blir jobbigt att simulera. Det bästa vore alltså att optimera direkt i scripten.
En form av ovanstående är predictive average, där man ser statistikt på föregående tider tex år eller månad.
Men om nu handelsklimaten skiljer sig år från år så försämrar det ju träffsäkerheten.

Själv skulle jag vara väldigt intresserad av att testa polynomanpassning av en kurva där man hela tiden anpassar tiden X bakåt och predikterar om kurvan bör öka tillräckligt inom en snar framtid för att det skall vara lönt att ta position.
Har någon av er som kör tex matlab testat med 3:e eller 5:e grads polynomanpassning?
Undrar
Bertil

[Bertil]

Igår blåste det och idag är det åska med kraftiga regnskurar, alltså helt perfekt för att filosofera och bygga strategier!

När USA började att experimentera med att flyga fortare än ljudet så förolyckades flera piloter. När det var piloten Chuck Yeagers tur att spaka experimentplanet så upptäckte han att vid överljudhastighet så måste man styra tvärt om!

Många som byggt strategier som inte fungerat så bra har ju testat att vända på strategin dvs sälja istället för att köpa då en viss edge uppnåtts. Men det är ju bara att erkänna att det inte heller blev så lyckat.

Men om man nu använder analogin med överljudsflygning så kanske det finns en brytpunkt dvs under denna punkt så skall man handla på ett visst sätt och över så skall man handla tvärt om!

Det är ju inte så konstigt. Tänk att om man närmar sig det övre Bollingerbandet och får en köptrigg då kanske man istället skall sälja.

Men om man inte använder Bollingerband, finns det andra brytpunkter som går att använda?

mvh
Bertil

[Bertil]

Jag har ju en strategi som heter volymsving där jag kvadrerar summan av volymen gånger priset två gånger och sedan delar med volymen samt tar kvadratroten ur två gånger. Alltså:
col=Div(Add(Add(c,H),L),3)
vol=MX(v,1)

hugo02=mov(mult(mult(mult(col,vol),mult(col,vol)),mult(mult(col,vol),mult(col,vol))),perioder01)
sliten02=mov(mult(mult(mult(vol,vol),vol),vol),perioder01)

not01=sqrt(sqrt(Div(hugo02,sliten02)))
not02=wild(not01,2)

Om man nu gör på samma sätt fast tar bort inverkan av den största volymen så får man

biggest=hhvbars(v,perioder01)
vyl=aref(vol,biggest)
cyl=aref(col,biggest)
hugo03=div(mult(mult(mult(cyl,vyl),mult(cyl,vyl)),mult(mult(cyl,vyl),mult(cyl,vyl))),perioder01)
sliten03=div(mult(mult(mult(vyl,vyl),vyl),vyl),perioder01)
hugo04=Sub(hugo02,hugo03)
sliten04=Sub(sliten02,sliten03)
not03=sqrt(sqrt(Div(hugo04,sliten04)))
not04=wild(not03,2)

Man kan nu definiera klimatet som skillnaden mellan kurvan där den största volymen ingår och kurvan där den största volymen är borttagen.

klimat=abs(Div(mov(sub(not04,not02),50),Mov(abs(Sub(not04,not02)),50)))
steg04=if(Lt(klimat,gräns02),steg03,steg02)
SetGVarIf(klimat,9000,1)

Gräns01 är den brytpunkt som jag pratade om i inlägget ovan där man säljer då man får en köptrigg och vice versa. Blir så här:

vallkor01=if(Gt(klimat,gräns01),Lt(sub(not02,not04),steg01),Gt(sub(not02,not04),steg04))
vallkor02=if(Gt(klimat,gräns01),Lt(not04,aref(not04,1)),Gt(not04,aref(not04,1)))
vallkor03=if(Gt(klimat,gräns01),Lt(not02,aref(not02,1)),Gt(not02,aref(not02,1)))
vallkor04=Gt(col,aref(col,1))
köpa=and(and(and(vallkor01,vallkor02),vallkor03),vallkor04)


mvh
Bertil

[Bertil]

Så här blir alltså köpscriptet i sin helhet:
----------
{ Mach1 köp }
{ 180811 }
innehav:=Portfolio(v)
ok_att_handla:=eqv(innehav,0)
steg01:=-1.5
steg02:=1.5
steg03:=1.0
Perioder01:=15
gräns01:=0.70
gräns02:=0.35

tidspärr1:=300
tidspärr2:=300

lt1:=LastTrade(S,D)
lt2:=LastTrade(B,D)
minSedanSälj:=Mult(Sub(Date(),lt1),1440)
minSedanKöp:=Mult(Sub(Date(),lt2),1440)
delay_ok:=gt(minSedanSälj,tidspärr1)
trans_ok:=gt(minSedanKöp,tidspärr2)

i5(
tid1=gt(int(mult(frac(d),1440)),660)
{ före kl 17.10 }
tid2=lt(int(mult(frac(d),1440)),1042)

col=Div(Add(Add(c,H),L),3)
vol=MX(v,1)

hugo02=mov(mult(mult(mult(col,vol),mult(col,vol)),mult(mult(col,vol),mult(col,vol))),perioder01)
sliten02=mov(mult(mult(mult(vol,vol),vol),vol),perioder01)

not01=sqrt(sqrt(Div(hugo02,sliten02)))
not02=wild(not01,2)

biggest=hhvbars(v,perioder01)
vyl=aref(vol,biggest)
cyl=aref(col,biggest)
hugo03=div(mult(mult(mult(cyl,vyl),mult(cyl,vyl)),mult(mult(cyl,vyl),mult(cyl,vyl))),perioder01)
sliten03=div(mult(mult(mult(vyl,vyl),vyl),vyl),perioder01)
hugo04=Sub(hugo02,hugo03)
sliten04=Sub(sliten02,sliten03)
not03=sqrt(sqrt(Div(hugo04,sliten04)))
not04=wild(not03,2)
klimat=abs(Div(mov(sub(not04,not02),50),Mov(abs(Sub(not04,not02)),50)))
steg04=if(Lt(klimat,gräns02),steg03,steg02)
SetGVarIf(klimat,9000,1)

Draw(not02,6,kqb0)
Draw(not04,3,gqb0)

vallkor01=if(Gt(klimat,gräns01),Lt(sub(not02,not04),steg01),Gt(sub(not02,not04),steg04))
vallkor02=if(Gt(klimat,gräns01),Lt(not04,aref(not04,1)),Gt(not04,aref(not04,1)))
vallkor03=if(Gt(klimat,gräns01),Lt(not02,aref(not02,1)),Gt(not02,aref(not02,1)))
vallkor04=Gt(col,aref(col,1))
köpa=and(and(and(vallkor01,vallkor02),vallkor03),vallkor04)

ditt_köpscript=And(And(And(And(köpa,tid1),tid2),delay_ok),trans_ok)
köpsignal=And(ditt_köpscript,ok_att_handla)
Mult(köpsignal,10)
)

mvh
Bertil

Angående val av parameternamn. Jag har ju flera hundra script med många hundra parametrar. För att särskilja dem så kan de få lite udda namn. Villkor är ju kor som går vill (vilse). Vallkor är ju kor som går vall.